* Albania 2008-09 wealth index - Trevor from Kiersten's Kenya-08.

freq qh101 qh108 qh109 qh111a qh111b qh111c qh111d qh111e qh111f qh111g qh111h qh111i qh111j qh111k
  qh111l qh111m qh111n qh111o qh111p qh111q qh111r qh111s qh111t qh117 qh118 qh119 qh120
  qh112 qh115 qh121a qh121b qh121c qh121d qh121e qh121f qh121g qh122
  qh124 qh125a qh125b qh125c qh125d qh125e qh125f qh125g qh126 qhmember.

*begin recoding into dichotomized variables.

*WATER SOURCE.

compute h2oires = 0.
if (qh101 = 11) h2oires = 1.
variable labels h2oires "if water is piped into residence".
value labels h2oires 0 "water not piped into residence"
			1 "water is piped into residence".

compute h2oyard = 0.
if (qh101 = 12) h2oyard = 1.
variable labels h2oyard "if water is piped into compound/plot".
value labels h2oyard 0 "water is not piped into compound/plot"
			  1 "water is piped into compound/plot".

compute h2opub = 0.
if (qh101 = 13) h2opub = 1.
variable labels h2opub "if gets water from a public tap".
value labels h2opub 0 "does not get water from a public tap"
			1 "gets water from a public tap".

compute h2otube = 0.
if (qh101 = 21) h2otube = 1.
variable labels h2otube "if gets water from tubewell or borehole".
value labels h2otube 0 "does not get water from tubewell or borehole"
			   1 "gets water from tubewell or borehole".

compute h2opwell = 0.
if (qh101 = 31) h2opwell = 1.
variable labels h2opwell "if gets water from a protected well".
value labels h2opwell 0 "does not get water from a protected well"
			   1 "gets water from a protected well".

compute h2upwell = 0.
if (qh101 = 32) h2upwell = 1.
variable labels h2upwell "if gets water from an unprotected well".
value labels h2upwell 0 "does not get water from an unprotected well"
			     1 "gets water from an unprotected well".

compute h2spring = 0.
if (qh101 = 41) h2spring = 1.
variable labels h2spring "if gets water from a protected spring".
value labels h2spring 0 "does not get water from a protected spring"
			    1 "gets water from a protected spring".

compute h2uspring = 0.
if (qh101 = 42) h2uspring = 1.
variable labels h2uspring "if gets water from an unprotected spring".
value labels h2uspring 0 "does not get water from an unprotected spring"
			    1 "gets water from an unprotected spring".

*compute h2osurf = 0.
*if (qh101 = 81) h2osurf = 1.
*variable labels h2osurf "if gets water from river, stream, pond, lake or dam".
*value labels h2osurf 0 "does not get water from surface sources"
			1 "gets water from surface sources".

*compute h2orain = 0.
*if (qh101 = 51) h2orain = 1.
*variable labels h2orain "if collects rainwater for drinking".
*value labels h2orain 0 "does not collect rainwater for drinking"
			1 "collects rainwater for drinking".

compute h2otk = 0.
if (qh101 = 61) h2otk = 1.
variable labels h2otk "if gets water from tanker truck or cart with sm tank".
value labels h2otk 0 "does not get water from truck/tank"
			1 "gets water from truck/tank".

compute h2obottl = 0.
if (qh101 = 71) h2obottl = 1.
variable labels h2obottl "if uses bottled drinking water".
value labels h2obottl 0 "does not use bottled drinking water"
			  1 "uses bottled drinking water".

compute h2oother = 0.
if (qh101 = 96 or qh101 = 51 or qh101 = 81) h2oother = 1.
variable labels h2oother "if gets water from other source (+2 rainwater, +2 surface water)".
value labels h2oother 0 "does not get water from other source"
			   1 "gets water from other source".


*TOILET TYPES.

compute flushs = 0.
if (qh108 = 11 & qh109 = 2) flushs = 1.
variable labels flushs "if has own flush toilet to sewer".
value labels flushs 0 "does not have own flush toilet to sewer"
		         1 "has own flush toilet to sewer".

compute shflushs = 0.
if (qh108 = 11 & qh109 = 1) shflushs = 1.
variable labels shflushs "if uses shared flush toilet to sewer".
value labels shflushs 0 "does not use shared flush toilet to sewer"
			1 "uses shared flush toilet to sewer".

compute flushsp = 0.
if (qh108 = 12) flushsp = 1.
variable labels flushsp "if has own flush toilet to septik".
value labels flushsp 0 "does not have own flush toilet to septik"
		         1 "has own flush toilet to septik".

*compute shflushsp = 0.
*if (qh108 = 12 & qh109 = 1) shflushsp = 1.
*variable labels shflushsp "if uses shared flush toilet to septik".
*value labels shflushsp 0 "does not use shared flush toilet to septik"
			1 "uses shared flush toilet to septik".

compute flushp = 0.
if (qh108 = 13) flushp = 1.
variable labels flushp "if has own flush toilet to pit latrine".
value labels flushp 0 "does not have own flush toilet to pit latrine"
		         1 "has own flush toilet to pit latrine".

*compute shflushp = 0.
*if (qh108 = 13 & qh109 = 1) shflushp = 1.
*variable labels shflushp "if uses shared flush toilet to pit latrine".
*value labels shflushp 0 "does not use shared flush toilet to pit latrine"
			1 "uses shared flush toilet to pit latrine".

compute flusho = 0.
if (qh108 > 14 & qh108 < 16) flusho = 1.
variable labels flusho "if has flush toilet to other".
value labels flusho 0 "does not have flush toilet to other"
		         1 "has flush toilet to other".

compute latvip = 0.
if (qh108 = 21) latvip = 1.
variable labels latvip "if uses pit latrine (VIP)".
value labels latvip 0 "does not use pit latrine"
		         1 "uses pit latrine".

compute latpits = 0.
if (qh108 = 22 | qh108 = 23) latpits = 1.
variable labels latpits "if uses pit latrine with/out slab".
value labels latpits 0 "does not use pit latrine with/out slab"
		         1 "uses pit latrine with/out slab".

*compute latpito = 0.
*if (qh108 = 23) latpito = 1.
*variable labels latpito "if uses pit latrine without slab".
*value labels latpito 0 "does not use pit latrine without slab"
		         1 "uses pit latrine without slab".

compute latcomp = 0.
if (qh108 = 31) latcomp = 1.
variable labels latcomp "if uses composting toilet".
value labels latcomp 0 "does not use composting toilet"
                     1 "uses composting toilet".

*AMENITIES.

compute radio = 0.
if (qh111a = 1) radio = 1.
variable labels radio "if household has radio".
value labels radio 0 "no radio"
		   1 "has radio".

compute tv = 0.
if (qh111b = 1) tv = 1.
variable labels tv "if household has tv".
value labels tv 0 "no tv"
		1 "has tv".

compute mphone = 0.
if (qh111c = 1) mphone = 1.
variable labels mphone "if household has mobile phone".
value labels mphone 0 "no mobile phone"
		    1 "house has mobile phone".

compute phone = 0.
if (qh111d = 1) phone = 1.
variable labels phone "if household has fixed phone".
value labels phone 0 "no fixed phone"
		   1 "has fixed phone".

compute video = 0.
if (qh111e = 1) video = 1.
variable labels video "if household has fixed video".
value labels video 0 "no fixed video"
		   1 "has fixed video".

compute tapecd = 0.
if (qh111f = 1) tapecd = 1.
variable labels tapecd "if household has fixed tapecd".
value labels tapecd 0 "no fixed tapecd"
		   1 "has fixed tapecd".

compute fridge = 0.
if (qh111g = 1) fridge = 1.
variable labels fridge "if household has fridge".
value labels fridge 0 "no fridge"
		    1 "has fridge".

compute freezer = 0.
if (qh111h = 1) freezer = 1.
variable labels freezer "if household has freezer".
value labels freezer 0 "no freezer"
		   1 "has freezer".

compute washmach = 0.
if (qh111i = 1) washmach = 1.
variable labels washmach "if household has washing machine".
value labels washmach 0 "no washing machine"
		   1 "has washing machine".

compute dishwash = 0.
if (qh111j = 1) dishwash = 1.
variable labels dishwash "if household has dishwasher".
value labels dishwash 0 "no dishwasher"
		   1 "has dishwasher".

compute microwave = 0.
if (qh111k = 1) microwave = 1.
variable labels microwave "if household has microwave".
value labels microwave 0 "no microwave"
		   1 "has microwave".

compute sofa = 0.
if (qh111l = 1) sofa = 1.
variable labels sofa "if household has sofa".
value labels sofa 0 "no sofa"
		   1 "has sofa".

compute armoire = 0.
if (qh111m = 1) armoire = 1.
variable labels armoire "if household has armoire".
value labels armoire 0 "no armoire"
		   1 "has armoire".

compute radiator = 0.
if (qh111n = 1) radiator = 1.
variable labels radiator "if household has radiator".
value labels radiator 0 "no radiator"
		   1 "has radiator".

compute generator = 0.
if (qh111o = 1) generator = 1.
variable labels generator "if household has generator".
value labels generator 0 "no generator"
		   1 "has generator".

compute sewmach = 0.
if (qh111p = 1) sewmach = 1.
variable labels sewmach "if household has sewing machine".
value labels sewmach 0 "no sewing machine"
		   1 "has sewing machine".

compute aircon = 0.
if (qh111q = 1) aircon = 1.
variable labels aircon "if household has air conditioner".
value labels aircon 0 "no air conditioner"
		   1 "has air conditioner".

compute boiler = 0.
if (qh111r = 1) boiler = 1.
variable labels boiler "if household has boiler".
value labels boiler 0 "no boiler"
		   1 "has boiler".

compute computer = 0.
if (qh111s = 1) computer = 1.
variable labels computer "if household has computer".
value labels computer 0 "no computer"
		   1 "has computer".

compute satellite = 0.
if (qh111t = 1) satellite = 1.
variable labels satellite "if household has satellite".
value labels satellite 0 "no satellite"
		   1 "has satellite".

compute watch = 0.
if (qh121a = 1) watch = 1.
variable labels watch "if household has watch".
value labels watch 0 "no watch"
		         1 "has watch".

compute bicycle = 0.
if (qh121b = 1) bicycle = 1.
variable labels bicycle "if household has bicycle".
value labels bicycle 0 "no bicycle"
		     1 "has bicycle".

compute motobk = 0.
if (qh121c = 1) motobk = 1.
variable labels motobk "if household has motorcycle or scooter".
value labels motobk 0 "no motorbike/scooter"
		    1 "has motorbike/scooter".

compute cart = 0.
if (qh121d = 1) cart = 1.
variable labels cart "if household has a cart".
value labels cart 0 "no cart"
		  1 "cart".

compute car = 0.
if (qh121e = 1) car = 1.
variable labels car "if household has car or truck".
value labels car 0 "no car/truck"
		 1 "has car/truck".

compute tractor = 0.
if (qh121f = 1) tractor = 1.
variable labels tractor "if household has tractor w motor".
value labels tractor 0 "no tractor"
		  1 "has tractor".

compute boat = 0.
if (qh121g = 1) boat = 1.
variable labels boat "if household has boat w motor".
value labels boat 0 "no boat"
		  1 "has boat".

compute sepkitch = 0.
if (qh115 = 1 | qh116 = 1) sepkitch = 1.
variable labels sepkitch "if cooking is done in a separate bldg or room".
value labels sepkitch	0 "no"
			1 "yes".

compute hectares = 0.
* Hectares.
if (qh123u = 1 & qh123 > 0) hectares = qh123.
* Dynym = 1/10 hectare.
if (qh123u = 2 & qh123 > 0) hectares = qh123/10.
* M2 - 1/10000 hectare.
if (qh123u = 3 & qh123 > 0) hectares = qh123/10000.

* QHMEMBER is number of de jure members, except for the following households.  See ExpHHChar.bch.
*066 015 has no de jure members. 2 de facto members.
*070 006 has no de jure members. 3 de facto members.
*073 005 has no de jure members. 1 de facto members.
*076 013 has no de jure members. 4 de facto members.
*083 012 has no de jure members. 1 de facto members.
*084 001 has no de jure members. 1 de facto members.
*085 015 has no de jure members. 1 de facto members.
*157 013 has no de jure members. 1 de facto members.
*178 015 has no de jure members. 2 de facto members.
*188 017 has no de jure members. 1 de facto members.
*222 001 has no de jure members. 3 de facto members.
*222 006 has no de jure members. 2 de facto members.
*246 008 has no de jure members. 2 de facto members.
*250 007 has no de jure members. 2 de facto members.
*305 004 has no de jure members. 1 de facto members.
*323 012 has no de jure members. 1 de facto members.
*363 007 has no de jure members. 4 de facto members.

compute memsleep = (qhmember/qh120).
variable labels memsleep "Number of members per sleeping room".

*FLOOR TYPE.

compute dirtfloo = 0.
if (qh117 = 11) dirtfloo = 1.
variable labels dirtfloo "if floor is earth/sand".
value labels dirtfloo 0 "floor is not earthen"
			1 "floor is earthen".

compute woodfloo = 0.
if (qh117 = 21) woodfloo = 1.
variable labels woodfloo "if floor is of wood planks".
value labels woodfloo 0 "floor is not of wood planks"
			   1 "floor is of wood planks".

compute parqfloo = 0.
if (qh117 = 31) parqfloo = 1.
variable labels parqfloo "if has parquet/polished wood flooring".
value labels parqfloo 0 "does not have parquet/polished wood flooring"
			1 "has parquet/polished wood flooring".

*compute vinfloo = 0.
*if (qh117 = 32) vinfloo = 1.
*variable labels vinfloo "if has linoleum flooring".
*value labels vinfloo 0 "does not have vinyl/asphalt strip flooring"
			1 "has vinyl/asphalt strip flooring".

compute cerafloo = 0.
if (qh117 = 33) cerafloo = 1.
variable labels cerafloo "if flooring is of ceramic tiles".
value labels cerafloo 0 "floor is not of ceramic tiles"
			  1 "floor is of ceramic tiles".

compute cemtfloo = 0.
if (qh117 = 34 | qh117 = 32) cemtfloo = 1.
variable labels cemtfloo "if floor is of cement (or vinyl/asphalt)".
value labels cemtfloo 0 "floor is not cement"
			  1 "floor is cement".

compute carpfloo = 0.
if (qh117 = 35) carpfloo = 1.
variable labels carpfloo "if has carpeted flooring".
value labels carpfloo 0 "does not have carpeted flooring"
			 1 "has carpeted flooring".

* TYPE OF WALL MATERIALS.

compute stnwall = 0.
if (qh119 = 22) stnwall = 1.
variable labels stnwall "if wall made of stone/mud".
value labels stnwall		0 "wall is not made of stone/mud"
				1 "wall is made of stone/mud".

*compute uadbwall = 0.
*if (qh119 = 23) uadbwall = 1.
*variable labels uadbwall "if wall made of uncovered adobe".
*value labels uadbwall	0 "wall is not made of uncovered adobe"
			1 "wall is made of uncovered adobe".

*compute rwdwall = 0.
*if (qh119 = 24 | qh119 = 25 | qh119 = 26) rwdwall = 1.
*variable labels rwdwall "if wall made ply/reused wood (+1 cardboard, +4 wood shingles)".
*value labels rwdwall		0 "wall is not made of ply/reused wood"
				1 "wall is made of ply/reused wood".

compute cmtwall = 0.
if (qh119 = 31) cmtwall = 1.
variable labels cmtwall "if wall made of cement".
value labels cmtwall	0 "wall is not made of cement"
				1 "wall is made of cement".

compute stncwall = 0.
if (qh119 = 32) stncwall = 1.
variable labels stncwall "if wall made of stone with cement".
value labels stncwall	0 "wall is not made of stone with cement"
				1 "wall is made of stone with cement".

compute brckwall = 0.
if (qh119 = 33) brckwall = 1.
variable labels brckwall "if wall made of brick".
value labels brckwall	0 "wall is not made of brick"
				1 "wall is made of brick".

compute blckwall = 0.
if (qh119 = 34) blckwall = 1.
variable labels blckwall "if wall made of cement block".
value labels blckwall	0 "wall is not made of cement block"
				1 "wall is made of cement block".

compute adbwall = 0.
if (qh119 = 35) adbwall = 1.
variable labels adbwall "if wall made of covered adobe".
value labels adbwall	0 "wall is not made of covered adobe"
				1 "wall is made of covered adobe".

*compute woodwall = 0.
*if (qh119 = 36) woodwall = 1.
*variable labels woodwall "if wall made of wood planks/shingles".
*value labels woodwall	0 "wall is not made of wood planks/shingles"
				1 "wall is made of wood planks/shingles".

compute othwall = 0.
if (qh119 = 23 | qh119 = 24 | qh119 = 25 | qh119 = 26 | qh119 = 36 | qh119 = 96) othwall = 1.
variable labels othwall "if wall made of other materials".
value labels othwall		0 "wall is not made of other materials"
				1 "wall is made of other materials".

*TYPE OF ROOFING MATERIALS.

compute matroof = 0.
if (qh118 = 21) matroof = 1.
variable labels matroof "if roof made of rustic mat".
value labels matroof 0 "roof not made of rustic mat"
			 1 "roof made of rustic mat".

compute wdplroof = 0.
if (qh118 = 23 | qh118 = 24) wdplroof = 1.
variable labels wdplroof "if has roof made of wood planks".
value labels wdplroof 0 "does not have roof made of wood planks"
			1 "has roof made of wood planks".

compute metalroof = 0.
if (qh118 = 31) metalroof = 1.
variable labels metalroof "if roof is made of metal".
value labels metalroof 0 "roof is not made of metal"
			   1 "roof is made of metal".

compute woodroof = 0.
if (qh118 = 32) woodroof = 1.
variable labels woodroof "if roof is made of wood".
value labels woodroof 0 "roof is not made of wood"
			   1 "roof is made of wood".

compute cfibroof = 0.
if (qh118 = 33) cfibroof = 1.
variable labels cfibroof "if roof made of cement fibre".
value labels cfibroof 0 "roof not made of cement fibre"
			   1 "roof made of cement fibre".

compute tileroof = 0.
if (qh118 = 34) tileroof = 1.
variable labels tileroof "if roof is made of tile".
value labels tileroof 0 "roof is not made of tile"
			1 "roof is made of tile".

compute cemroof = 0.
if (qh118 = 35) cemroof = 1.
variable labels cemroof "if roof made of cement".
value labels cemroof 0 "roof not made of cement"
			   1 "roof made of cement".

compute shngroof = 0.
if (qh118 = 36) shngroof = 1.
variable labels shngroof "if roof made of wood shingles".
value labels shngroof 0 "roof not made of wood shingles"
			   1 "roof made of wood shingles".

compute concroof = 0.
if (qh118 = 37) concroof = 1.
variable labels concroof "if roof is made of concrete".
value labels concroof 0 "roof is not made of concrete"
			   1 "roof is made of concrete".


*TYPE OF COOKING FUEL.

compute cookelec = 0.
if (qh112 = 1) cookelec = 1.
variable labels cookelec "if uses electricity for cooking".
value labels cookelec 0 "does not use electricity for cooking"
			   1 "uses electricity for cooking".

compute cookLPG = 0.
if (qh112 = 2) cookLPG = 1.
variable labels cookLPG "if uses LPG for cooking".
value labels cookLPG 0 "does not use LPG for cooking"
			   1 "uses LPG for cooking".

compute cookgas = 0.
if (qh112 = 3 | qh112 = 5) cookgas = 1.
variable labels cookgas "if uses natural gas (+1 kerosene) for cooking".
value labels cookgas 0 "does not use gas for cooking"
			   1 "uses gas for cooking".

compute cookwood = 0.
if (qh112 > 6 & qh112 < 9) cookwood = 1.
variable labels cookwood "if uses wood, charcoal (+10) for cooking fuel".
value labels cookwood 0 "does not use firewood for cooking"
			     1 "uses firewood for cooking".

compute cookoth = 0.
if (qh112 = 95) cookoth = 1.
variable labels cookoth "no food cooked in HH".
value labels cookoth 0 "food is cooked in HH/ no other fuel for cooking"
		 	  1 "no food cooked in hh".

* Assume at least 1 for DK - could use median?.
if (missing(qh125a) or qh125a = 98) qh125a = 1.
if (missing(qh125b) or qh125b = 98) qh125b = 1.
if (missing(qh125c) or qh125c = 98) qh125c = 1.
if (missing(qh125d) or qh125d = 98) qh125d = 1.
if (missing(qh125e) or qh125e = 98) qh125e = 1.
if (missing(qh125f) or qh125f = 98) qh125f = 1.
if (missing(qh125g) or qh125g = 98) qh125g = 1.

* Dichotomize agricultural ownership variables.
if (qh125a >= 1) qh125a = 1.
if (qh125b >= 1) qh125b = 1.
if (qh125c >= 1) qh125c = 1.
if (qh125d >= 1) qh125d = 1.
if (qh125e >= 1) qh125e = 1.
if (qh125f >= 1) qh125f = 1.
if (qh125g >= 1) qh125g = 1.

* Prodice dichotomous variables for small, medium and large land ownership (roughly to match units reported - M2=1/10000, Dynym=1/10, Hectares=1).
compute hects = 0.
if (hectares > 0 and hectares < 0.1) hects = 1.
compute hectm = 0.
if (hectares >= 0.1 and hectares < 1) hectm = 1.
compute hectl = 0.
if (hectares >= 1) hectl = 1.

compute bank = 0.
if (qh126 = 1) bank = 1.
variable labels bank "if has bank account".
value labels bank 0 "no bank account"
		  1 "has bank account".

execute.

weight off.

freq
h2oires h2oyard h2opub h2otube h2opwell h2upwell h2spring h2uspring h2otk h2obottl h2oother
flushs shflushs flushsp flushp flusho latvip latpits latcomp
radio tv mphone phone video tapecd fridge freezer washmach dishwash microwave sofa
armoire radiator generator sewmach aircon boiler computer satellite
watch bicycle motobk cart car tractor boat sepkitch memsleep bank
dirtfloo woodfloo parqfloo cerafloo cemtfloo carpfloo 
stnwall cmtwall stncwall brckwall blckwall adbwall othwall
matroof wdplroof metalroof woodroof cfibroof tileroof cemroof shngroof concroof
cookelec cookLPG cookgas cookwood cookoth
hects hectm hectl qh125a qh125b qh125c qh125d qh125e qh125f qh125g.

factor
  /variables
h2oires h2oyard h2opub h2otube h2opwell h2upwell h2spring h2uspring h2otk h2obottl h2oother
flushs shflushs flushsp flushp flusho latvip latpits latcomp
radio tv mphone phone video tapecd fridge freezer washmach dishwash microwave sofa
armoire radiator generator sewmach aircon boiler computer satellite
watch bicycle motobk cart car tractor boat sepkitch memsleep bank
dirtfloo woodfloo parqfloo cerafloo cemtfloo carpfloo 
stnwall cmtwall stncwall brckwall blckwall adbwall othwall
matroof wdplroof metalroof woodroof cfibroof tileroof cemroof shngroof concroof
cookelec cookLPG cookgas cookwood cookoth
hects hectm hectl qh125a qh125b qh125c qh125d qh125e qh125f qh125g 
  /missing meansub
  /analysis
h2oires h2oyard h2opub h2otube h2opwell h2upwell h2spring h2uspring h2otk h2obottl h2oother
flushs shflushs flushsp flushp flusho latvip latpits latcomp
radio tv mphone phone video tapecd fridge freezer washmach dishwash microwave sofa
armoire radiator generator sewmach aircon boiler computer satellite
watch bicycle motobk cart car tractor boat sepkitch memsleep bank
dirtfloo woodfloo parqfloo cerafloo cemtfloo carpfloo 
stnwall cmtwall stncwall brckwall blckwall adbwall othwall
matroof wdplroof metalroof woodroof cfibroof tileroof cemroof shngroof concroof
cookelec cookLPG cookgas cookwood cookoth
hects hectm hectl qh125a qh125b qh125c qh125d qh125e qh125f qh125g 
  /PRINT UNIVARIATE INITIAL EXTRACTION FSCORE
  /CRITERIA FACTORS(1) ITERATE(25)
  /EXTRACTION PC
  /ROTATION NOROTATE
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

compute hhmemwt = qhweight/1000000 * qhmember.
variable labels hhmemwt 'HH members weighting for Index' .

weight by hhmemwt.
freq
variables=fac1_1
/FORMAT=NOTABLE
/NTILES= 5
/STATISTICS=STDDEV MINIMUM MAXIMUM MEAN MEDIAN
/ORDER ANALYSIS .

RANK
  VARIABLES=FAC1_1  (A) /RANK /NTILES (5) /PRINT=YES
  /TIES=MEAN .
rename variables (nfac1_1=wlthind5).
variable labels wlthind5 'Wealth Index Quintiles'.
value labels wlthind5 1 'Poorest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Richest'.

recode fac1_1
(lowest thru -1.09708=1)
(-1.09709 thru -0.45740=2)
(-0.45741 thru  0.38541=3)
( 0.38542 thru  0.90171=4)
( 0.90172 thru highest=5) into wlthind5x .
variable labels wlthind5x 'Wealth Index Quintiles'.
value labels wlthind5x 1 'Poorest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Richest'.
execute.

write outfile='C:\Projects\Macro\Albania 2008\DP\ADHS\Wealth\scores.dat' records=1 table
/qhclust qhnumber fac1_1 wlthind5.
execute.

means
  tables=
h2oires h2oyard h2opub h2otube h2opwell h2upwell h2spring h2uspring h2otk h2obottl h2oother
flushs shflushs flushsp flushp flusho latvip latpits latcomp
radio tv mphone phone video tapecd fridge freezer washmach dishwash microwave sofa
armoire radiator generator sewmach aircon boiler computer satellite
watch bicycle motobk cart car tractor boat sepkitch memsleep bank
dirtfloo woodfloo parqfloo cerafloo cemtfloo carpfloo 
stnwall cmtwall stncwall brckwall blckwall adbwall othwall
matroof wdplroof metalroof woodroof cfibroof tileroof cemroof shngroof concroof
cookelec cookLPG cookgas cookwood cookoth
hects hectm hectl qh125a qh125b qh125c qh125d qh125e qh125f qh125g 
 by wlthind5
  /cells mean.

freq wlthind5.

weight off.
freq wlthind5.

compute wt = qhweight/1000000.
weight by wt.
freq wlthind5.